home *** CD-ROM | disk | FTP | other *** search
/ Apple II Magazines (PO) / Nibble Volume 13, No. 03 (1992-03)(MindCraft Publishing)(Side A).zip / Nibble Volume 13, No. 03 (1992-03)(MindCraft Publishing)(Side A).po / SWAP.S < prev    next >
Text File  |  1996-12-24  |  7KB  |  290 lines
  1. * SWAP VARIABLES
  2. * COPYRIGHT (C) 1982
  3. * DIGIPAC COMPUTER CONSULTING
  4.           REP 40
  5. *
  6. * APPLESOFT USAGE
  7. *
  8.           REP 40
  9. CHKCOM    EQU $DEBE
  10. CHKOPN    EQU $DEBB
  11. CHRGET    EQU $B1
  12. CHRGOT    EQU $B7
  13. FNDLIN    EQU $D61A
  14. FRMNUM    EQU $DD67
  15. GETADR    EQU $E752
  16. LINNUM    EQU $50
  17. SYNERR    EQU $DEC9
  18.           REP 40
  19. *
  20. * ZERO PAGE
  21. *
  22.           REP 40
  23. LEN1      EQU $8
  24. LEN2      EQU $9
  25. NXTLIN    EQU $19
  26. THSLIN    EQU $9B
  27.           REP 40
  28. *
  29. * CONSTANTS
  30. * 
  31.           REP 40
  32.           MSB OFF
  33. COMMA     EQU ','
  34. CLOSE     EQU ')'
  35. QUOTE     EQU '"'
  36. COLON     EQU ':'
  37. EOL       EQU 0
  38. REM       EQU 178
  39. DATA      EQU 131
  40. OPEN      EQU '('
  41. INTEGER   EQU '%'
  42. STRING    EQU '$'
  43.           MSB ON
  44. *
  45. * STORAGE
  46. *
  47. VBLSTR    EQU $200
  48. *
  49.           ORG $9470 
  50. *
  51.           REP 40
  52. *
  53. * MAIN SEQUENCE
  54. *
  55.           REP 40
  56.           JSR CHKOPN     ; IS OPENING '('?
  57.           JSR FRMNUM     ; GET STARTING LINE 
  58.           JSR GETADR
  59.           LDA LINNUM
  60.           STA STRLIN     ; STORE STARTING LINE NUMBER 
  61.           LDA LINNUM+1
  62.           STA STRLIN+1
  63.           JSR CHKCOM
  64.           JSR FRMNUM     ; GET ENDING LINE 
  65.           JSR GETADR
  66.           LDA LINNUM
  67.           STA ENDLIN     ; STORE ENDING LINE NUMBER 
  68.           LDA LINNUM+1
  69.           STA ENDLIN+1
  70. STRTFND   LDA STRLIN     ; RESTORE START LINE # TO ZERO PAGE 
  71.           STA LINNUM
  72.           LDA STRLIN+1
  73.           STA LINNUM+1
  74.           JSR FNDLIN     ; FIND THE STARTING LINE 
  75.           JSR FNDVAR 
  76. STRTSCH   JSR SRCHLIN    ; SEARCH LINE FOR VARIABLES 
  77.           JSR LASTCHK
  78.           LDA #CLOSE     ; IS THIS LAST LINE? 
  79.           CMP LINFLG 
  80.           BNE NULINE     ; NO, GET THE NEXT LINE 
  81.           LDA #CLOSE     ; ARE THERE MORE VARIABLES? 
  82.           CMP ENDFLG 
  83.           BNE STRTFND    ; THEN GET NEXT SET OF VARIABLES 
  84.           RTS            ; RETURN TO BASIC
  85. NULINE    JSR NEXTLINE 
  86.           JMP STRTSCH
  87.           REP 40
  88. *
  89. * FIND AND STORE VARIABLES
  90. *
  91.           REP 40
  92. FNDVAR    JSR CHRGOT
  93.           CMP #COMMA     ; IF NO COMMA THEN SYNTAX ERROR 
  94.           BEQ INITIAL 
  95. ERR       JSR SYNERR
  96. INITIAL   LDX #0
  97.           LDY #0
  98.           JSR GETCHAR
  99.           CPX #0 
  100.           BEQ ERR        ; NO FIRST VARIABLE 
  101.           CMP #CLOSE  
  102.           BEQ ERR        ; NO SECOND VARIABLE ERROR 
  103.           DEX
  104.           STX LEN1       ; STORE LENGTH OF FIRST VARIABLE 
  105.           LDX #0
  106.           JSR GETCHAR
  107.           CPX #0         ; SECOND VARIABLE IS A BLANK 
  108.           BEQ ERR        ;NO SECOND VARIABLE ERROR 
  109.           DEX
  110.           STX LEN2       ; STORE SECOND VARIABLE LENGTH 
  111.           RTS
  112.           REP 40
  113. *
  114. * SEARCH THE LINE
  115. *
  116.           REP 40
  117. SRCHLIN   LDX #0 
  118.           JSR OLDLNK 
  119.           JSR LASTCHK
  120.           LDY #4
  121. GETDAT    LDA (THSLIN),Y ; GET CHARACTER, THEN CHECK FOR 
  122.           CMP #EOL       ; : END OF LINE 
  123.           BEQ RETURN1
  124.           CMP #REM       ; : REM? 
  125.           BEQ RETURN1
  126.           CMP #QUOTE     ; : QUOTED STRING? 
  127.           BEQ STRTQUO
  128.           CMP #DATA      ; : DATA STATEMENT? 
  129.           BEQ STRTDAT
  130.           CMP VBLSTR,X   ; COMPARE TO STORED VARIABLE 
  131.           BEQ STRGSAM
  132.           INY
  133.           LDX #0
  134.           JMP GETDAT     ; NO MATCH- GET ANOTHER 
  135. STRGSAM   CPX LEN1       ; IF END OF VARIABLE NAME REACHED 
  136.           BEQ SWAP       ; THEN GO TO SWAP 
  137.           INX            ; ELSE GET ANOTHER CHARACTER 
  138.           INY
  139.           JMP GETDAT
  140. SWAP      JSR SWAPVAR    ; RUN SWAPPING ROUTINE 
  141.           INY
  142.           LDX #0         ; RESET FOR NEXT OCCURANCE 
  143.           JMP GETDAT
  144. STRTDAT   LDA #COLON     ; FIND NEXT BASIC STATEMENT 
  145.           STA COMPAR 
  146.           JSR FINDCLS
  147. NEWSTM    CMP #EOL 
  148.           BEQ RETURN1 
  149.           JMP GETDAT
  150. STRTQUO   LDA #QUOTE     ; FIND ENDING QUOTE 
  151.           STA COMPAR 
  152.           JSR FINDCLS 
  153.           JMP NEWSTM
  154. RETURN1   RTS 
  155.           REP 40
  156. *
  157. * MAKE THE SWAP
  158. *
  159.           REP 40
  160. SWAPVAR   INY
  161.           LDA (THSLIN),Y ; CHECK FOR VARIABLE TYPE MATCH
  162.           CMP #STRING
  163.           BEQ RETURN2
  164.           CMP #INTEGER
  165.           BEQ RETURN2
  166.           CMP #OPEN
  167.           BEQ RETURN2
  168.           DEY            ; MOVE POINTER TO BEG OF VARIABLE 
  169.           TYA
  170.           SEC
  171.           SBC LEN1
  172.           TAY
  173.           INX
  174.           LDA LEN2       ; USE VARIABLE LENGTH 2 AS A COUNTER
  175.           STA VBLLEN
  176.           INC VBLLEN
  177. MOVCHAR   LDA VBLSTR,X 
  178.           STA (THSLIN),Y ; MAKE THE SWAP 
  179.           INY
  180.           INX
  181.           DEC VBLLEN 
  182.           BNE MOVCHAR    ; ALL SECOND VARIABLE TRANSFERRED? 
  183.           JSR MAKLEN
  184.           RTS
  185. RETURN2   DEY
  186.           RTS
  187.           REP 40
  188. *
  189. * FIND END OF QUOTE OR DATA STATEMENT 
  190. *
  191. FINDCLS   INY
  192. NEXT1     LDA (THSLIN),Y
  193.           CMP #EOL       ; LOOK FOR END OF LINE 
  194.           BEQ ENDLIN1
  195.           INY
  196.           CMP COMPAR     ; LOOK FOR COLON OR QUOTE 
  197.           BNE NEXT1
  198. ENDLIN1   RTS
  199.           REP 40
  200. *
  201. * GET AND STORE A VARIABLE CHARACTER
  202. *
  203.           REP 40
  204. GETCHAR   LDA #0 
  205.           STA ENDFLG     ; CLEAR END FLAG 
  206. GETCHR1   JSR CHRGET     ; NEXT CHARACTER IN CALLING SEQUENCE 
  207.           CMP #COMMA     ; EACH VARIABLE TERMINATED BY ',' 
  208.           BEQ RETURN3 
  209.           CMP #CLOSE     ; OR ')' 
  210.           BEQ CLOSE1
  211.           STA VBLSTR,Y   ; SAVE THE CHARACTER 
  212.           INX
  213.           INY
  214.           JMP GETCHR1    ; GET ANOTHER CHARACTER 
  215. CLOSE1    JSR CHRGET
  216.           LDA #CLOSE     ; LAST VARIABLE FOUND 
  217.           STA ENDFLG
  218. RETURN3   RTS
  219.           REP 40
  220. *
  221. * CHECK IF LAST LINE REACHED
  222. *
  223.           REP 40
  224. LASTCHK   LDY #3 
  225.           LDA (THSLIN),Y
  226.           CMP ENDLIN+1   ; COMPARE CURRENT LINE# TO LAST 
  227.           BCC RETURN4
  228.           DEY
  229.           LDA (THSLIN),Y
  230.           CMP ENDLIN
  231.           BCC RETURN4
  232.           LDA #CLOSE     ; SET THE LAST LINE FLAG 
  233.           STA LINFLG 
  234.           RTS
  235. RETURN4   LDA #0
  236.           STA LINFLG
  237.           RTS
  238.           REP 40
  239. *
  240. * SET POINTER TO NEXT LINE
  241. *
  242.           REP 40
  243. NEXTLINE  LDA NXTLIN 
  244.           STA THSLIN
  245.           LDA NXTLIN+1
  246.           STA THSLIN+1
  247.           RTS 
  248.           REP 40
  249. * 
  250. * SAVE THE NEXT LINK ADDRESS
  251. *
  252.           REP 40
  253. OLDLNK    LDY #0
  254.           LDA (THSLIN),Y ;SAVE NEXT LINE ADDRESS 
  255.           STA NXTLIN
  256.           INY
  257.           LDA (THSLIN),Y
  258.           STA NXTLIN+1 
  259.           RTS
  260.           REP 40
  261. *
  262. * MAKE LENGTH OF VARIABLES THE SAME
  263. *
  264.           REP 40
  265. MAKLEN    LDA LEN1
  266.           SEC
  267.           SBC LEN2
  268.           BEQ RETURN5    ; IF SAME LENGTH THEN EXIT 
  269.           BMI RETURN5    ; IF LEN1 < LEN 2 THEN EXIT
  270.           STA TEMP       ; SAVE LENGTH REMAINING
  271. STORBLK   LDA #$20
  272.           STA (THSLIN),Y ; SAVE A BLANK
  273.           INY
  274.           DEC TEMP
  275.           BNE STORBLK
  276. RETURN5   RTS
  277.           REP 40
  278. *
  279. * STORAGE
  280. *
  281.           REP 40
  282. COMPAR    DS 1
  283. ENDFLG    DS 1
  284. ENDLIN    DS 2
  285. LINFLG    DS 1
  286. STRLIN    DS 2
  287. VBLLEN    DS 1
  288. TEMP      DS 1
  289.           LST OFF
  290.